本帖最后由 爱上老公 于 2015-2-28 18:07 编辑
如题,全前台,全TC,完美世界的朋友可以来交流下,内存党无视
废话少说,上代码
上个附件,直接用
空间 完美世界国际版2自动打怪辅助
窗口句柄
线程句柄
结果
功能 打怪()
//热键0启动后,首先做了一个任务血量的判断,之前用的是模糊找色,现在用的找图,先截取满血状态时千位数子,
//然后循环判断指定点是否找到该图,没找打就加血.
是否找到1,是否找到2,是否找到3,图片X坐标,图片Y坐标,图像序号,图片X1坐标,图片Y1坐标,图像序号1
变量 x,y
辅助.截图(190,68,195,82,"rc:3.bmp")
辅助.等待(1000)
文件.移动("rc:3.bmp","d:\\3.bmp")
循环(真)
是否找到1=图像.模糊找色(180,65,281,86,#AF2C1E,0.8,0,x,y)
//是否找到2=图像.模糊找色(255,63,278,85,#AF2C1E,0.8,0,x,y)
是否找到3=图像.模糊找色(199,84,255,100,#24ABB3,0.8,0,x,y)
//用模糊找色判断指定点颜色,没找打就启动逃命功能模块
如果(是否找到1==0)
完美世界国际版2自动打怪辅助.逃命()
标签.设置文本("标签1","继续")
线程.暂停(线程句柄)
如果结束
完美世界国际版2自动打怪辅助.捡东西()//捡东西功能模块
图像序号=图像.找图(152,66,164,82,"d:\\3.bmp",#102030,0.7,0,图片X坐标,图片Y坐标)
如果(图片X坐标<0)
//辅助.消息框(类型.转字符型(图片X坐标))
完美世界国际版2自动打怪辅助.加血()
否则
完美世界国际版2自动打怪辅助.执行打怪()//如果血量足,则执行打怪
如果结束
//如果(是否找到2==0)
// 完美世界国际版2自动打怪辅助.加血()
//否则
// 完美世界国际版2自动打怪辅助.执行打怪()
//如果结束
如果(是否找到3==0)//加蓝
完美世界国际版2自动打怪辅助.加蓝()
如果结束
图像序号1=图像.找图(69,122,97,149,"rc:木毒.bmp",#102030,0.6,0,图片X1坐标,图片Y1坐标)
如果(图片X1坐标>0)//如果任务头像下出现中毒图标,则执行解毒功能
完美世界国际版2自动打怪辅助.解毒()
如果结束
循环结束
功能结束
功能 逃命()
键盘.按键(50)//2加血
辅助.等待(50)
键盘.按键(114)//技能F3键加血
辅助.等待(100)
键盘.按键(53)//5飞
辅助.等待(50)
键盘.按下(32)
辅助.等待(15000)
键盘.弹起(32)
功能结束
功能 加血()
键盘.按键(50)//2加血
辅助.等待(50)
键盘.按键(114)//技能F3键加血
功能结束
功能 加蓝()
键盘.按键(51)//3加蓝
辅助.等待(50)
功能结束
功能 解毒()
键盘.按键(117)
功能结束
功能 捡东西()
键盘.按键(52,1)//4捡东西
辅助.等待(200)
键盘.按键(52,1)//4捡东西
辅助.等待(200)
键盘.按键(52,1)//4捡东西
辅助.等待(200)
功能结束
功能 执行打怪()
//根据按钮内容来判断打怪模式
内容=按钮.获得文本("按钮0")
如果(内容=="指定打怪")
完美世界国际版2自动打怪辅助.随机打怪()
如果结束
如果(内容=="不打指定怪")
完美世界国际版2自动打怪辅助.指定打怪()
如果结束
如果(内容=="随机打怪")
完美世界国际版2自动打怪辅助.不打指定怪()
如果结束
功能结束
功能 打怪步骤()
//由于本人使用MM职业测试的,所以对有法术抵抗属性的怪物另外用了7键技能,一般怪物用1键放技能
图像序号,图片X坐标,图片Y坐标
图像序号=图像.找图(566,117,733,140,"rc:法术抵抗.bmp",#102030,1.0,0,图片X坐标,图片Y坐标)
如果(图片X坐标>0)
键盘.按键(55,1)//7放技能
辅助.等待(3000)
否则
键盘.按键(49,1)//1放技能
辅助.等待(3000)
如果结束
功能结束
功能 随机打怪()
//用模糊找色判断怪物血条是否存在,存在则执行打怪步奏,否则按tab取怪
是否找到1,x,y
是否找到1=图像.模糊找色(575,48,597,84,#B61316,0.8,0,x,y)
如果(是否找到1==0)
键盘.按键(9,1)
辅助.等待(200)
否则
完美世界国际版2自动打怪辅助.打怪步骤()
如果结束
功能结束
功能 不打指定怪()
图片X坐标,图片Y坐标,图像序号
图片X1坐标,图片Y1坐标,图像序号1
图片X2坐标,图片Y2坐标,图像序号2
如果(单选框.获得状态("单选框0"))
图像序号=图像.找图(539,40,783,114,"rc:11.bmp",#102030,0.8,0,图片X坐标,图片Y坐标)
如果(图片X坐标>0)
键盘.按键(9)
否则
完美世界国际版2自动打怪辅助.打怪步骤()
如果结束
如果结束
如果(单选框.获得状态("单选框1"))
图像序号1=图像.找图(539,40,783,114,"rc:12.bmp",#102030,0.8,0,图片X1坐标,图片Y1坐标)
如果(图片X1坐标>0)
键盘.按键(9)
否则
完美世界国际版2自动打怪辅助.打怪步骤()
如果结束
如果结束
如果(单选框.获得状态("单选框2"))
图像序号2=图像.找图(539,40,783,114,"rc:13.bmp",#102030,0.8,0,图片X2坐标,图片Y2坐标)
如果(图片X2坐标>0)
键盘.按键(9)
否则
完美世界国际版2自动打怪辅助.打怪步骤()
如果结束
如果结束
功能结束
功能 指定打怪()
图片X坐标,图片Y坐标,图像序号
图片X1坐标,图片Y1坐标,图像序号1
图片X2坐标,图片Y2坐标,图像序号2
如果(单选框.获得状态("单选框0"))
图像序号=图像.找图(539,40,783,114,"rc:11.bmp",#102030,0.8,0,图片X坐标,图片Y坐标)
如果(图片X坐标>0)
完美世界国际版2自动打怪辅助.打怪步骤()
否则
键盘.按键(9)
如果结束
如果结束
如果(单选框.获得状态("单选框1"))
图像序号1=图像.找图(539,40,783,114,"rc:12.bmp",#102030,0.8,0,图片X1坐标,图片Y1坐标)
如果(图片X1坐标>0)
完美世界国际版2自动打怪辅助.打怪步骤()
否则
键盘.按键(9)
如果结束
如果结束
如果(单选框.获得状态("单选框2"))
图像序号2=图像.找图(539,40,783,114,"rc:13.bmp",#102030,0.8,0,图片X2坐标,图片Y2坐标)
如果(图片X2坐标>0)
完美世界国际版2自动打怪辅助.打怪步骤()
否则
键盘.按键(9)
如果结束
如果结束
功能结束
功能 热键0_热键()
//热键0开始脚本
窗口句柄=窗口.找到窗口("完美世界国际版2")
结果=窗口.是否存在(窗口句柄)
窗口.还原(窗口句柄)
窗口.设置位置(窗口句柄,0,0)
窗口.置顶(窗口句柄,真)
辅助.等待(3000)
时间=类型.转整型(编辑框.获得文本("编辑框1"))*60000
定时器.注册("定时器0",1000000)
定时器.注册("定时器1",1000)
如果(时间>1000)
定时器.注册("定时器2",类型.转整型(时间))
控件.有效("热键2",假)
否则
控件.有效("热键2",真)
如果结束
线程句柄=线程.开启("完美世界国际版2自动打怪辅助.打怪","")
功能结束
功能 热键0_失去焦点()
热键.销毁("热键0")
热键.注册("热键0")
功能结束
功能 热键1_热键()
//热键1暂停和继续脚本
内容=标签.获得文本("标签1")
如果(内容=="继续")
标签.设置文本("标签1","暂停")
线程.恢复(线程句柄)
否则
标签.设置文本("标签1","继续")
线程.暂停(线程句柄)
如果结束
功能结束
功能 热键1_失去焦点()
热键.销毁("热键1")
热键.注册("热键1")
功能结束
功能 热键2_热键()
//热键2结束脚本
线程.关闭(线程句柄)
定时器.销毁("定时器0")
定时器.销毁("定时器1")
定时器.销毁("定时器2")
文件.删除("d:\\3.bmp")
//辅助.退出()
功能结束
功能 热键2_失去焦点()
热键.销毁("热键2")
热键.注册("热键2")
功能结束
功能 定时器0_时钟()
//用定时器给人物加状态
线程.暂停(线程句柄)//暂停进程,起飞加状态
辅助.等待(100)
键盘.按键(54)//6加状态
辅助.等待(10000)
线程.恢复(线程句柄)
功能结束
功能 定时器1_时钟()
//用定时器获取系统时间,在编辑框显示
时间=系统.时间(3)
编辑框.设置文本("编辑框0",字符串.连接(类型.转字符型(时间),"正在挂机!"))
功能结束
功能 定时器2_时钟()//定时打怪,达到编辑框1指定时间后暂停线程句柄并起飞待命,同时结束热键失效
控件.有效("热键2",真)
编辑框.设置文本("编辑框1","")
标签.设置文本("标签1","继续")
线程.暂停(线程句柄)
辅助.等待(100)
键盘.按键(53)//5飞
辅助.等待(50)
键盘.按下(32)
辅助.等待(15000)
键盘.弹起(32)
定时器.销毁("定时器2")
功能结束
功能 按钮0_点击()
//按下按钮0,设置按钮内容
按钮内容=按钮.获得文本("按钮0")
如果(按钮内容=="随机打怪")
按钮.设置文本("按钮0","指定打怪")
如果结束
如果(按钮内容=="指定打怪")
按钮.设置文本("按钮0","不打指定怪")
如果结束
如果(按钮内容=="不打指定怪")
按钮.设置文本("按钮0","随机打怪")
如果结束
功能结束
功能 按钮1_点击()
//按钮1刷新怪物,原理:先指定区域截屏,截取怪物名字,先截取第一个,按tab换怪,然后判断第一张图是否存在,
//存在则继续tab换怪,不存在则截屏第二张图,第三张类似,如果按tab换怪,第一张和第二张都没有找到
//则截屏第三张图片,如果循环5次都只有一种怪,则只有第一张图,3个图片框分别显示3张图,旁边3个单选框,对应
//单选框被选中,脚本打指定怪或者不打指定怪
按钮内容=按钮.获得文本("按钮1")
如果(按钮内容=="刷新")
按钮.设置文本("按钮1","等待刷新")
完美世界国际版2自动打怪辅助.刷新怪物()
否则
按钮.设置文本("按钮1","刷新")
如果结束
功能结束
功能 刷新怪物()
图片X坐标,图片Y坐标,图像序号
图片X1坐标,图片Y1坐标,图像序号1
图片X2坐标,图片Y2坐标,图像序号2
文件.删除("rc:11.bmp")
辅助.等待(50)
文件.删除("rc:12.bmp")
辅助.等待(50)
文件.删除("rc:13.bmp")
辅助.等待(50)
窗口句柄=窗口.找到窗口("完美世界国际版2")
窗口.置顶(窗口句柄,真)
辅助.等待(50)
窗口.设置位置(窗口句柄,0,0)
辅助.等待(2000)
键盘.按键(9)
辅助.等待(500)
辅助.截图(607,78,725,94,"rc:11.bmp")
辅助.等待(500)
图片框.设置图片("图片框0","rc:11.bmp")
遍历(5)
是否存在
辅助.等待(500)
图像序号=图像.找图(539,40,783,114,"rc:11.bmp",#102030,1.0,0,图片X坐标,图片Y坐标)
如果(图片X坐标<0)
辅助.截图(607,78,725,94,"rc:12.bmp")
辅助.等待(500)
图片框.设置图片("图片框1","rc:12.bmp")
辅助.等待(300)
否则
键盘.按键(9)
辅助.等待(300)
如果结束
是否存在=文件.是否存在("rc:12.bmp")
如果(是否存在)
跳出
如果结束
遍历结束
遍历(5)
是否存在1
辅助.等待(500)
图像序号1=图像.找图(539,40,783,114,"rc:12.bmp",#102030,1.0,0,图片X1坐标,图片Y1坐标)
图像序号2=图像.找图(539,40,783,114,"rc:11.bmp",#102030,1.0,0,图片X2坐标,图片Y2坐标)
如果(图片X1坐标>0||图片X2坐标>0)
键盘.按键(9)
辅助.等待(300)
否则
辅助.截图(607,78,725,94,"rc:13.bmp")
辅助.等待(500)
图片框.设置图片("图片框2","rc:13.bmp")
辅助.等待(300)
如果结束
是否存在1=文件.是否存在("rc:13.bmp")
如果(是否存在1)
跳出
如果结束
遍历结束
功能结束
空间结束
|